Excel Datenbank mit Eingabemaske: Tutorial & Download für Anfänger

Ich werde oft gefragt, wie man eine effektive Eingabemaske für Excel-Tabellen erstellt. Aus diesem Grund habe ich ein umfassendes Tutorial entwickelt, das Ihnen Schritt für Schritt zeigt, wie Sie eine funktionale und benutzerfreundliche Eingabemaske realisieren. Dieses Tutorial konzentriert sich auf eine kleine Adressliste und ist speziell für Einsteiger und Anfänger konzipiert. Es soll Ihnen die ersten Schritte mit VBA und UserForms erleichtern und Ihnen ermöglichen, das Beispiel später eigenständig zu erweitern.

Hinweis: Dieses Tutorial verwendet Microsoft Office Professional Version 2013 und Windows 7. Bei anderen Versionen kann es zu geringfügigen Unterschieden im Erscheinungsbild kommen. Nutzer von Microsoft Office für Mac müssen ebenfalls mit Abweichungen rechnen, die hier nicht spezifisch behandelt werden.

Am Ende dieses Tutorials finden Sie einen praktischen Download-Link zur fertigen Beispieldatei, damit Sie das Ergebnis sofort nutzen können. So erhalten Sie schnell und unkompliziert Ihre “Excel Datenbank Mit Eingabemaske Download”.

Neue Version des Tutorials verfügbar

Für fortgeschrittenere Anwender oder alle, die ihr Wissen vertiefen möchten, empfehle ich auch einen Blick auf die bereits verfügbare Version 2 des Tutorials, die einen alternativen Quelltext detaillierter beleuchtet und weitere Optimierungen zeigt.

Die Ausgangslage und unsere Zielsetzung

Unser Hauptziel ist die Erstellung einer Adressliste, die durch eine intuitive Eingabemaske verwaltet wird. Diese Eingabemaske soll eine Reihe von essenziellen Funktionen bieten, um die Datenerfassung und -verwaltung in Ihrer Excel-Datenbank zu optimieren:

• Anzeige vorhandener Daten: Beim Öffnen der Eingabemaske sollen alle bereits erfassten Namen übersichtlich in einer Liste auf der Maske angezeigt werden. Dies sorgt für eine schnelle Übersicht über den Datenbestand.
• Detailansicht: Ein Klick auf einen Namen in dieser Liste soll die zugehörigen Adressinformationen in speziellen Textfeldern (Textboxen) der Eingabemaske darstellen. So können Sie Details gezielt einsehen.
• Datensatz bearbeiten und speichern: Änderungen an den angezeigten Informationen können einfach vorgenommen und über einen “Speichern”-Knopf direkt in die Excel-Tabelle übertragen werden. Dies gewährleistet die Aktualität Ihrer Daten.
• Neue Einträge hinzufügen: Eine dedizierte Schaltfläche “Adresse hinzufügen” ermöglicht das Anlegen neuer Datensätze, wodurch die Erweiterung Ihrer Adressliste zum Kinderspiel wird.
• Einträge löschen: Mit einer “Löschen”-Schaltfläche können existierende Einträge unkompliziert und schnell entfernt werden, um die Datenbank sauber zu halten.

Dieses Tutorial legt den Fokus auf grundlegendes Wissen. Komplexere Funktionen wie umfangreiche Eingabeprüfungen oder Fehlerbehandlungsroutinen werden hier nicht behandelt. Diese Themen stellen jedoch hervorragende Erweiterungsmöglichkeiten dar, wären aber für einen ersten Schritt für Anfänger zu viel auf einmal.

Betrachten wir zunächst unsere Ausgangsbasis. Ich habe eine einfache Beispieltabelle erstellt. Wenn Sie dieses Beispiel nachbauen möchten, öffnen Sie bitte jetzt Microsoft Excel und eine neue, leere Arbeitsmappe.

Wichtige Annahme für dieses Beispiel: Es wird davon ausgegangen, dass jeder von uns eingegebene Name nur EINMAL existiert. Wenn Ihre zukünftige Tabelle eine eindeutige Kennung wie eine Rechnungsnummer oder eine laufende Nummer enthält, können Sie diese verwenden, um Datensätze in der Programmierung eindeutig zu identifizieren. Daher steht in der Überschrift “Name (ID)”, um zu verdeutlichen, dass diese Spalte als primäres Erkennungszeichen für jeden Datensatz dient.

Die Eingabemaske erstellen

Nachdem wir unsere Datengrundlage in Excel angelegt haben, widmen wir uns der Erstellung unserer Eingabemaske. Zuerst entwerfen wir das Layout der Benutzeroberfläche, die in VBA auch als UserForm bezeichnet wird.

Drücken Sie dazu in Excel die Tastenkombination ALT + F11. Dadurch öffnet sich die integrierte Entwicklungsumgebung (IDE) von VBA.

Auf der linken Seite sehen Sie den “Projekt-Explorer”. Hier sind alle geöffneten Arbeitsmappen und Add-Ins aufgelistet. Klappen Sie Ihre aktuelle Datei mithilfe des Pluszeichens (+) auf, falls sie nicht bereits geöffnet ist. Sollten der Projekt-Explorer oder das Eigenschaftenfenster nicht sichtbar sein, können Sie diese über das Menü “Ansicht” der Entwicklungsumgebung einblenden.

VBA Entwicklungsumgebung mit Projekt-Explorer und Eigenschaftenfenster

Nun sehen Sie alle Tabellen, Formulare und Module Ihrer Datei. Klicken Sie mit der rechten Maustaste auf Ihre Datei (z.B. “VBAProject (IhreDateiman_e.xlsm)”) und wählen Sie im Kontextmenü Einfügen -> UserForm.

UserForm in Excel VBA einfügen über das Kontextmenü

Eine neue UserForm namens “UserForm1” wird erstellt und im Projekt-Explorer angezeigt. Doppelklicken Sie auf “UserForm1”, um sie im Entwurfsmodus zu öffnen.

Leere UserForm1 und ihr Eigenschaftenfenster in Excel VBA

Im Eigenschaftenfenster, das sich standardmäßig rechts unten befindet, sehen Sie den Namen der Eingabemaske: “UserForm1”. Für dieses Beispiel belassen wir diesen Namen unverändert. In zukünftigen Projekten können Sie eigene Namen verwenden, müssen diese dann aber im Code entsprechend anpassen. Die Größe der UserForm lässt sich einfach per Drag & Drop an den Rändern anpassen.

Der nächste Schritt ist die eigentliche Gestaltung unserer Benutzeroberfläche. Hierfür benötigen wir die “Werkzeugsammlung” (oder “Toolbox”). Sollte diese nicht automatisch angezeigt werden, blenden Sie sie bitte über das Menü “Ansicht” der Entwicklungsumgebung ein. Klicken Sie in der Werkzeugsammlung auf das Icon des Objekts, das Sie hinzufügen möchten (z.B. “ListBox”, “TextBox”, “CommandButton”), und ziehen Sie es dann wie beim Zeichnen eines Rahmens auf die graue Fläche Ihrer UserForm1. Wenn Sie sich unsicher sind, welches Icon wofür steht, halten Sie den Mauszeiger darüber, bis der ToolTipp-Text erscheint.

Für unsere UserForm1 benötigen wir folgende Elemente:

• 1x ListBox (Name: ListBox1) – zum Anzeigen der Namen.
• 6x TextBox (Namen: TextBox1 bis TextBox6) – zur Anzeige und Bearbeitung der Adressdetails.
• 1x CommandButton (Name: CommandButton_1 – Beschriftung/Caption: Neuer Eintrag) – zum Hinzufügen neuer Adressen.
• 1x CommandButton (Name: CommandButton_2 – Beschriftung/Caption: Löschen) – zum Entfernen bestehender Adressen.
• 1x CommandButton (Name: CommandButton_3 – Beschriftung/Caption: Speichern) – zum Speichern von Änderungen.
• 1x CommandButton (Name: CommandButton_4 – Beschriftung/Caption: Beenden) – zum Schließen der Eingabemaske.
• 7x Label – zur Beschriftung der Textboxen und zur besseren Orientierung auf der Oberfläche.

Das fertige Layout könnte dann ungefähr so aussehen:

Fertig gestaltete Excel UserForm als Eingabemaske für eine Adressliste

Hinweis zur Gestaltung und Benennung: Wenn Sie ein Objekt auf der UserForm1 anklicken (z.B. eine TextBox oder einen CommandButton), sehen Sie im Eigenschaftenfenster zahlreiche Einstellungsmöglichkeiten. Die wichtigste Eigenschaft ist der “(Name)”. Dieser muss exakt so benannt sein, wie in der obigen Liste angegeben (z.B. ListBox1, TextBox1), da sonst unser VBA-Code nicht korrekt funktioniert. Um den Text eines Labels oder die Beschriftung eines CommandButtons zu ändern, verwenden Sie die Eigenschaft “Caption” im Eigenschaftenfenster. Alternativ können Sie ein Label markieren und mit einem weiteren Klick in den Editiermodus wechseln, um den Text direkt anzupassen.

Nachdem wir die Oberfläche gestaltet haben, folgt nun die eigentliche Programmierung der Funktionalitäten.

Die Funktionalitäten der Eingabemaske erstellen

Um unserer Benutzeroberfläche “Leben einzuhauchen”, müssen wir den einzelnen Steuerelementen (Schaltflächen, Liste) Funktionen zuweisen. Dies geschieht durch das Einfügen von VBA-Code in die entsprechenden Ereignisprozeduren.

Doppelklicken Sie zunächst auf die “Beenden”-Schaltfläche (unseren CommandButton_4) auf Ihrer UserForm1. Der Quellcode-Editor wird geöffnet, und Sie sehen möglicherweise bereits einen leeren Codeblock. Löschen Sie diesen und fügen Sie den folgenden vollständigen VBA-Quelltext ein. Die ausführlichen Kommentare im Code (in grüner Schrift) erklären dabei die Funktion jeder Zeile, sodass Sie genau nachvollziehen können, was passiert.

Ergebnisse statt Aufwand & Arbeit?
Wir liefern Ergebnisse – schicken Sie uns kurz Ihre Datei und Ihre Wünsche; wir integrieren den notwendigen Code professionell, beheben ggf. vorhandene Fehler, machen optional ein Code-Review, liefern bei Bedarf Performance-Optimierungen & setzen gewünschte Erweiterungen effizient für Sie um (und das zum Festpreis nach kurzer Sichtung).
Express-Service beauftragen

Der Quelltext für Ihre Excel Datenbank mit Eingabemaske

Probleme? Express-Hilfe! 

Option Explicit
Option Compare Text
' Original-Quelltext unter: https://www.online-vba.de/vba-tutorial-eingabemaske-fuer-excel-tabelle
' Express-Hilfe für VBA unter https://www.online-vba.de/vba-expresshilfe
' Es gelten die Nutzungsbedingungen von Online-VBA.de

'Neuer Eintrag Schaltfläche Ereignisroutine
Private Sub CommandButton1_Click()
   Dim lZeile As Long
   'Wenn der Benutzer einen neuen Eintrag erzeugen möchte,
   'erstellen wir einen neuen Eintrag in der ListBox und markieren
   'diesen, damit der Benutzer die Daten eintragen kann

   lZeile = 2 'Start in Zeile 2, Zeile 1 sind ja die Überschriften
   'Schleife, solange etwas in der ersten Spalte in Tabelle 1 drin steht
   Do While Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) <> ""
       lZeile = lZeile + 1 'Nächste Zeile bearbeiten
   Loop

   'Nach Durchlauf dieser Schleife steht lZeile in der ersten leeren Zeile von Tabelle1
   'Neuen Eintrag in die Tabelle1 schreiben, Spalte ID muss gefüllt sein, damit
   'unsere Routinen die Zeile wiederfinden!
   Tabelle1.Cells(lZeile, 1) = CStr("Neuer Eintrag Zeile " & lZeile)

   'Und neuen Eintrag in die UserForm eintragen
   ListBox1.AddItem CStr("Neuer Eintrag Zeile " & lZeile)

   'Den neuen Eintrag markieren mit Hilfe des ListIndexes
   ListBox1.ListIndex = ListBox1.ListCount - 1
   'Durch das Click Ereignis der ListBox werden die Daten automatisch geladen

End Sub

'Löschen Schaltfläche Ereignisroutine
Private Sub CommandButton2_Click()
   Dim lZeile As Long
   'Wenn kein Datensatz in der ListBox markiert wurde, wird die Routine beendet
   If ListBox1.ListIndex = -1 Then Exit Sub
   'Zum Löschen benötigen wir die Zeilennummer des ausgewählten Datensatzes
   lZeile = 2 'Start in Zeile 2, Zeile 1 sind ja die Überschriften
   'Schleife solange etwas in der ersten Spalte in Tabelle 1 drin steht
   Do While Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) <> ""
       'Datensatz ID Spalte mit selektiertem Eintrag der ListBox vergleichen
       If ListBox1.Text = Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) Then
           'Eintrag gefunden, die ganze Zeile wird nun gelöscht
           Tabelle1.Rows(CStr(lZeile & ":" & lZeile)).Delete
           'Die ListBox muss nun neu geladen werden!
           Call UserForm_Initialize
           If ListBox1.ListCount > 0 Then ListBox1.ListIndex = 0
           Exit Do 'Vorzeitiges Ende, da der Datensatz schon gefunden ist
       End If
       lZeile = lZeile + 1 'Nächste Zeile bearbeiten
   Loop
End Sub

'Speichern Schaltfläche Ereignisroutine
Private Sub CommandButton3_Click()
   Dim lZeile As Long
   'Wenn kein Datensatz in der ListBox markiert wurde, wird die Routine beendet
   If ListBox1.ListIndex = -1 Then Exit Sub
   'Wir müssen prüfen, ob die ID Spalte auch gefüllt ist!!
   If Trim(CStr(TextBox1.Text)) = "" Then
       'Meldung ausgeben
       MsgBox "Sie müssen mindestens einen Namen eingeben!", vbCritical + vbOKOnly, "FEHLER!"
       'Abbrechen der Speicherroutine
       Exit Sub
   End If
   'Ausbauoption: Prüfen, ob die ID in Tabelle1 Spalte 1 schon vorhanden ist!
   'Zum Speichern benötigen wir die Zeilennummer des ausgewählten Datensatzes
   lZeile = 2 'Start in Zeile 2, Zeile 1 sind ja die Überschriften
   'Schleife, solange etwas in der ersten Spalte in Tabelle 1 drin steht
   Do While Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) <> ""
       'Datensatz ID Spalte mit selektiertem Eintrag der ListBox vergleichen
       If ListBox1.Text = Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) Then
           'Eintrag gefunden, TextBoxen in die Zellen schreiben
           Tabelle1.Cells(lZeile, 1).Value = Trim(CStr(TextBox1.Text))
           Tabelle1.Cells(lZeile, 2).Value = TextBox2.Text
           Tabelle1.Cells(lZeile, 3).Value = TextBox3.Text
           Tabelle1.Cells(lZeile, 4).Value = TextBox4.Text
           Tabelle1.Cells(lZeile, 5).Value = TextBox5.Text
           Tabelle1.Cells(lZeile, 6).Value = TextBox6.Text
           'Die ListBox muss nun neu geladen werden
           'allerdings nur, wenn sich der Name (ID) geändert hat
           If ListBox1.Text <> Trim(CStr(TextBox1.Text)) Then
               Call UserForm_Initialize
               If ListBox1.ListCount > 0 Then ListBox1.ListIndex = 0
           End If
           Exit Do 'Vorzeitiges Ende, da der Datensatz schon gefunden ist
       End If
       lZeile = lZeile + 1 'Nächste Zeile bearbeiten
   Loop
End Sub

'Beenden Schaltfläche Ereignisroutine
Private Sub CommandButton4_Click()
   Unload Me
End Sub

'Klick auf die ListBox Ereignisroutine
Private Sub ListBox1_Click()
   Dim lZeile As Long
   'Wenn der Benutzer einen Namen anklickt, suchen wir
   'diesen in der Tabelle1 heraus und tragen die Daten
   'in die TextBoxen ein.
   'Wir löschen standardmäßig alle bisherigen TextBoxen-Inhalte
   TextBox1 = ""
   TextBox2 = ""
   TextBox3 = ""
   TextBox3 = ""
   TextBox4 = ""
   TextBox5 = ""
   TextBox6 = ""
   'Nur wenn ein Eintrag selektiert/markiert ist
   If ListBox1.ListIndex >= 0 Then
       lZeile = 2 'Start in Zeile 2, Zeile 1 sind ja die Überschriften
       'Schleife, solange etwas in der ersten Spalte in Tabelle 1 drin steht
       Do While Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) <> ""
           'Wenn wir den Namen aus der ListBox1 in der Tabelle1 Spalte 1
           'gefunden haben, übertragen wir die anderen Spalteninhalte
           'in die TextBoxen!
           If ListBox1.Text = Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) Then
               'TextBoxen füllen
               TextBox1 = Trim(CStr(Tabelle1.Cells(lZeile, 1).Value))
               TextBox2 = Tabelle1.Cells(lZeile, 2).Value
               TextBox3 = Tabelle1.Cells(lZeile, 3).Value
               TextBox4 = Tabelle1.Cells(lZeile, 4).Value
               TextBox5 = Tabelle1.Cells(lZeile, 5).Value
               TextBox6 = Tabelle1.Cells(lZeile, 6).Value
               Exit Do 'Vorzeitiges Ende, da der Datensatz schon gefunden ist
           End If
           lZeile = lZeile + 1 'Nächste Zeile bearbeiten
       Loop
   End If
End Sub

Private Sub UserForm_Activate()
   'Wenn die Eingabemaske angezeigt wird, markieren wir den ersten Namen
   'jedoch nur, wenn auch Einträge in der Liste stehen
   If ListBox1.ListCount > 0 Then
       ListBox1.ListIndex = 0
   End If
End Sub

'Startroutine, wird ausgeführt bevor die Eingabemaske angezeigt wird
Private Sub UserForm_Initialize()
   Dim lZeile As Long
   'Alle TextBoxen leer machen
   TextBox1 = ""
   TextBox2 = ""
   TextBox3 = ""
   TextBox4 = ""
   TextBox5 = ""
   TextBox6 = ""
   'In dieser Routine laden wir alle vorhandenen
   'Einträge in die ListBox1
   ListBox1.Clear 'Zuerst einmal die Liste leeren
   lZeile = 2 'Start in Zeile 2, Zeile 1 sind ja die Überschriften
   'Schleife, solange etwas in der ersten Spalte in Tabelle 1 drin steht
   Do While Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) <> ""
       'Aktuelle Zeile in die ListBox eintragen
       ListBox1.AddItem Trim(CStr(Tabelle1.Cells(lZeile, 1).Value))
       lZeile = lZeile + 1 'Nächste Zeile bearbeiten
   Loop
End Sub

Eine Schaltfläche erstellen, welche die Eingabemaske öffnet

Nachdem wir die UserForm und den zugehörigen VBA-Code erstellt haben, müssen wir noch eine Möglichkeit schaffen, die Eingabemaske direkt aus unserer Excel-Tabelle heraus zu starten. Sie können die VBA-Entwicklungsumgebung nun schließen und zu Ihrem Excel-Tabellenblatt wechseln.

Stellen Sie sicher, dass der Excel-Reiter “Entwicklertools” in Ihrem Menüband sichtbar ist. Falls nicht, gehen Sie bitte in die Excel-Optionen (Datei -> Optionen -> Menüband anpassen) und aktivieren Sie dort die Anzeige der “Entwicklertools”.

Excel Entwicklertools aktivieren im Menüband

Klicken Sie nun im Reiter “Entwicklertools” auf “Einfügen” (in der Gruppe “Steuerelemente”) und wählen Sie unter “Formularsteuerelemente” die “Schaltfläche” aus. Platzieren Sie diese neue Schaltfläche auf Ihrem Tabellenblatt “Tabelle1” an der gewünschten Stelle.

Nachdem Sie die Schaltfläche eingefügt haben, öffnet sich automatisch ein Fenster zur “Makro zuweisen”. Klicken Sie dort auf “Neu”. Die Entwicklungsumgebung wird sich erneut öffnen, und es erscheint ein leeres Code-Fenster für das Click-Ereignis Ihrer Schaltfläche. Fügen Sie hier die Zeile UserForm1.Show zwischen die bereits vorhandenen Zeilen ein, wie im folgenden Screenshot dargestellt.

VBA Code zum Öffnen der UserForm1 durch eine Schaltfläche

Schließen Sie die Entwicklungsumgebung und kehren Sie zur Excel-Tabelle zurück. Damit sind alle notwendigen Schritte abgeschlossen, und Ihre “excel datenbank mit eingabemaske download” ist einsatzbereit!

Jetzt testen wir!

Nun ist der Moment gekommen, alles auszuprobieren! Klicken Sie auf die soeben erstellte Schaltfläche in Ihrer Excel-Tabelle, um die Eingabemaske zu öffnen. Testen Sie alle Funktionen in Ruhe: Fügen Sie neue Einträge hinzu, bearbeiten Sie bestehende Adressen, speichern Sie Änderungen und löschen Sie Datensätze. Erleben Sie, wie die Datenbank mit Eingabemaske Ihre Arbeit erleichtert.

Funktionierende Excel Eingabemaske mit Adressdaten zur Datenerfassung

Schlusswort

Ich hoffe, dieses einfache, aber detaillierte Tutorial hat Ihnen die ersten Schritte zur Erstellung Ihrer eigenen Excel Eingabemaske erleichtert. Es gibt selbstverständlich zahlreiche Möglichkeiten für Erweiterungen, Design-Anpassungen und Funktionsverbesserungen. Wie das Sprichwort sagt: “Man kann immer mehr dazu bauen und hübscher geht auch immer!” Diese weiteren Schritte überlasse ich jedoch Ihnen selbst.

Ich wünsche Ihnen viel Erfolg und Freude beim Einsatz Ihrer ersten, selbst erstellten oder angepassten Excel Datenbank mit Eingabemaske!

Das könnte Sie auch interessieren:
Wir übernehmen die Excel-Migration – Bestandsaufnahme, Portierung von Makros/Daten und saubere Übergabe in eine wartbare Struktur. Regional unterstützen wir Sie mit einem VBA-Entwickler für Köln – Festpreise und direkter Ansprechpartner.

Download der Beispieldatei

Als praktischer Service steht Ihnen die in diesem Tutorial verwendete Beispieldatei zum direkten Download zur Verfügung. Nutzen Sie diese, um das Beispiel nachzuvollziehen oder als Grundlage für Ihre eigenen Projekte einer “excel datenbank mit eingabemaske download”.

DOWNLOAD

• Dateiformat: *.xlsm
• Erstellt mit: Microsoft Excel Version 2013
• Kompatibilität: Microsoft Excel Version 2007 oder neuer
• Dateigröße: ca. 31 KiloBytes

Anmerkungen und Hinweise

Dieser Codeschnipsel wurde von Marc Wershoven im Jahr 2013 erstellt. Die Nutzung erfolgt auf eigene Gefahr. Bitte denken Sie immer zuerst an eine ausreichende Datensicherung. Wir können leider keinen kostenlosen Support für diese Inhalte anbieten. Es gelten unsere Nutzungsbedingungen.

Wichtiger Hinweis für Downloads:
Die Autoren von Online-VBA.de stellen Dateien als kostenlosen Service zum Download bereit. Dieser Download erfolgt stets auf eigene Gefahr. Bitte beachten Sie die Nutzungsbedingungen, bevor Sie die Datei herunterladen. Ein kostenloser Support oder Service für die hier veröffentlichen Werke kann leider nicht angeboten werden!

So einfach läuft unsere VBA-Expresshilfe ab

1. Senden Sie uns Ihre Office-Datei oder Ihren VBA-Code (gerne anonymisiert) mit einer kurzen Problembeschreibung oder Ihrem Erweiterungswunsch per E-Mail.
2. Wir analysieren Ihr Anliegen schnell und schicken Ihnen umgehend (tagsüber meist innerhalb von 1-2 Stunden) ein Festpreis-Angebot.
3. Nach Ihrer Zustimmung lösen wir Ihr Problem (meist noch am gleichen Tag) oder setzen Ihre Erweiterung zuverlässig um – inklusive verständlicher Dokumentation der durchgeführten Maßnahmen.

Jetzt VBA-Notfallhilfe anfordern!